Ролевое программирование в Bold

Пример реализации паттерна Актор/Роль в Bold.


Пример реализации паттерна Актор/Роль в Bold.

Ролевое программирование в Bold

Bold позволяет разработчикам создавать ООП-приложения с сохранением данных в базе. Это даёт возможность использовать наследование, однако такой подход легко применить избыточно.

В качестве примера приведу модель из приложения, которое я однажды разрабатывал на Bold:

UMLInheritance.jpg

Приведённая структура позволяет регистрировать заказы на покупку для клиента (Customer), назначать административную работу сотруднику (AdminEmployee) и хранить информацию о рейсах для пилота (Pilot).

Ролевой подход

Проблема этого подхода возникает, когда роли начинают пересекаться. Например, сотрудник может стать клиентом, или пилот может выполнять административную работу на условиях частичной занятости.

Решение — использовать паттерн Актор/Роль. Каждый Актор (абстрактный класс) может получать несколько Ролей (тоже абстрактный класс). Именно с Ролями связана бизнес-информация. Например, с PilotRole связана информация о рейсах, а с CustomerRole — заказы на покупку.

Обновлённая модель будет выглядеть примерно так:

UMLActor.jpg

  1. Актор может не иметь ролей или иметь несколько ролей.
  2. Конкретный экземпляр Актора может запрещать удаление роли.
  3. Роль может отказывать в применении к конкретному Актору.
  4. Роль может указывать, что она является обязательной и не может быть удалена (например, LoginRole нельзя удалить, потому что у пользователя также есть SystemAdministratorRole).
  5. Конкретный экземпляр Актора может отклонить роль.

Листинг 1: Actor

//Принять или отклонить роль
function TActor.CanAcceptRole(ARoleClass: TRoleClass): Boolean;
begin
if not ARoleClass.AllowDuplicates and HasRole(ARoleClass, nil) then
Result := False
else
if not ARoleClass.AllowActiveDuplicates and
HasActiveRole(ARoleClass, nil) then
Result := False
else
Result := ARoleClass.CanApplyTo(Self);
end;



//Разрешить или запретить удаление роли
function TActor.CanRemoveRole(ARole: TRole): Boolean;
begin
Result := not ARole.IsRequired;
end;



//Возвращает роль, только если она активна
function TActor.FindActiveRole(AClass: TClass; ExcludeInstance: TRole): TRole;
var
I: Integer;
begin
Result := nil;
for I := 0 to Roles.Count - 1 do
if Roles[I].Active and (Roles[I].ClassType = AClass) and
(Roles[I] <> ExcludeInstance) then
begin
Result := Roles[I];
Break;
end;
end;



//Возвращает роль вне зависимости от её активности
function TActor.FindRole(AClass: TClass; ExcludeInstance: TRole): TRole;
var
I: Integer;
begin
Result := nil;
for I := 0 to Roles.Count - 1 do
if (Roles[I].ClassType = AClass) and
(Roles[I] <> ExcludeInstance) then
begin
Result := Roles[I];
Break;
end;
end;



//Возвращает True, если Актор владеет указанной ролью и она активна
function TActor.HasActiveRole(AClass: TClass; ExcludeInstance: TRole): Boolean;
begin
Result := Assigned(FindActiveRole(AClass, ExcludeInstance));
end;



//Возвращает True, если Актор владеет указанной ролью (активной или неактивной)
function TActor.HasRole(AClass: TClass; ExcludeInstance: TRole): Boolean;
begin
Result := Assigned(FindRole(AClass, ExcludeInstance));
end;



function TActor.ReceiveQueryFromOwned(Originator: TObject; OriginalEvent: TBoldEvent;
const Args: array of const; Subscriber: TBoldSubscriber): Boolean;
var
ObjectLocator: TBoldObjectLocator;
Role: TRole;
begin
Result := inherited ReceiveQueryFromOwned(Originator, OriginalEvent, Args, Subscriber);
if not Result or BoldObjectIsDeleted then Exit; //Проверка добавления ролей
if (Originator = M_Roles) then
begin
if OriginalEvent = bqMayInsert then
begin
//Получить добавляемую роль
Assert(Args[1].VType = vtObject);
ObjectLocator := (Args[1].VObject as TBoldObjectLocator);
Role := (ObjectLocator.BoldObject as TRole); //Проверка дублирующихся ролей, которые не разрешены
if (not Role.AllowDuplicates) and
(HasRole(Role.ClassType, nil)) then
begin
Result := False;
SetBoldLastFailureReason(
TBoldFailureReason.Create('Эта роль может быть применена только один раз', Self)
);
end else
//Проверка дублирующихся активных ролей, которые не разрешены
if (not Role.AllowActiveDuplicates) and
(HasActiveRole(Role.ClassType, nil)) then
begin
Result := False;
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно применить эту роль, так как ' +
'уже существует активная роль такого типа', Self)
);
end else
Result := CanAcceptRole(TRoleClass(Role.ClassType));
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Роль не может быть применена к этому объекту', Self)
);
end else //bqMayInsert
//Проверка удаления ролей
if OriginalEvent = bqMayRemove then
begin
//Получить удаляемый объект роли
Assert(Args[0].VType = vtInteger);
Role := Roles[Args[0].VInteger];
Result := (not Role.Active) or (not Role.IsRequired);
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Роль не может быть удалена, ' +
'она требуется другой активной ролью', Self)
);
end; //bqMayRemove
end;
end;

Листинг 2: Role

//Разрешить или запретить применение к конкретному Актору
class function TRole.CanApplyTo(AObject: TActor): Boolean;
begin
Result := False;
end;



//Виртуальный метод для переопределения в потомках, описывающий роль
class function TRole.GetRoleName: string;
begin
Result := '';
end;



//Опционально, указывает, разрешены ли активные дубликаты
class function TRole.AllowActiveDuplicates: Boolean;
begin
Result := False;
end;



//Опционально, указывает, разрешены ли дубликаты (активные или неактивные)
class function TRole.AllowDuplicates: Boolean;
begin
Result := False;
end;



//Возвращает True, если какая-либо роль зависит от наличия этой роли
function TRole.IsRequired: Boolean;
var
I: Integer;
begin
if Actor <> nil then
begin
Result := True;
for I := 0 to Actor.Roles.Count - 1 do
if Actor.Roles[I] <> self then
if Actor.Roles[I].RequiresRole(self) then
Exit;
end;
Result := False;
end;



//Переопределите этот метод, чтобы указать зависимость от другой роли
function TRole.RequiresRole(ARole: TRole): Boolean;
begin
Result := False;
end;



//Заполняет производный атрибут RoleName из метода класса
procedure TRole._RoleName_DeriveAndSubscribe(DerivedObject: TObject; Subscriber: TBoldSubscriber);
begin
inherited;
M_RoleName.AsString := GetRoleName;
end;



//Предотвращает удаление обязательной роли
function TRole.MayDelete: Boolean;
begin
Result := not IsRequired;
end;



function TRole.ReceiveQueryFromOwned(Originator: TObject; OriginalEvent: TBoldEvent;
const Args: array of const; Subscriber: TBoldSubscriber): Boolean;
begin
Result := inherited ReceiveQueryFromOwned(Originator,
OriginalEvent, Args, Subscriber);
if not Result then Exit;
if (Originator = M_Active) then //Атрибут Active
begin
if OriginalEvent = bqMayModify then
begin
if Actor = nil then
Result := True
else
if Active then
begin
//Запретить деактивацию, если другая роль требует,
//чтобы эта роль была активна
Result := not IsRequired;
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно деактивировать эту роль, ' +
'другие роли зависят от неё', Self)
);
end else
begin
//Запретить повторную активацию, если уже существует активная роль
//и дубликаты не разрешены
Result := AllowActiveDuplicates or (not Actor.HasActiveRole(Self.ClassType, Self));
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно активировать эту роль, ' +
'так как уже существует похожая активная роль', Self)
);
end;
end; //bqMayModify
end; //Атрибут Active
end;

Весь приведённый выше код является абстрактным. Остаётся лишь создать конкретные классы, унаследованные от Actor и Role.

UMLRoles.jpg

Заключение

Вместо того чтобы иметь отдельные классы Employee и Customer, мы теперь можем легко назначить EmployeeRole или CustomerRole любому объекту типа Person (который является Актором).

Кроме того, роли можно комбинировать: пилот может выполнять административную работу, а клиентом может быть кто угодно — человек, отдел, компания или даже страна.

Надеюсь, эта статья оказалась полезной.








Ролевое программирование в Bold


Пример реализации паттерна Актор/Роль в Bold.


Пример реализации паттерна Актор/Роль в Bold.

Ролевое программирование в Bold

Bold позволяет разработчикам создавать ООП-приложения с сохранением данных в базе. Это даёт возможность использовать наследование, однако такой подход легко применить избыточно.

В качестве примера приведу модель из приложения, которое я однажды разрабатывал на Bold:

UMLInheritance.jpg

Приведённая структура позволяет регистрировать заказы на покупку для клиента (Customer), назначать административную работу сотруднику (AdminEmployee) и хранить информацию о рейсах для пилота (Pilot).

Ролевой подход

Проблема этого подхода возникает, когда роли начинают пересекаться. Например, сотрудник может стать клиентом, или пилот может выполнять административную работу на условиях частичной занятости.

Решение — использовать паттерн Актор/Роль. Каждый Актор (абстрактный класс) может получать несколько Ролей (тоже абстрактный класс). Именно с Ролями связана бизнес-информация. Например, с PilotRole связана информация о рейсах, а с CustomerRole — заказы на покупку.

Обновлённая модель будет выглядеть примерно так:

UMLActor.jpg

  1. Актор может не иметь ролей или иметь несколько ролей.
  2. Конкретный экземпляр Актора может запрещать удаление роли.
  3. Роль может отказывать в применении к конкретному Актору.
  4. Роль может указывать, что она является обязательной и не может быть удалена (например, LoginRole нельзя удалить, потому что у пользователя также есть SystemAdministratorRole).
  5. Конкретный экземпляр Актора может отклонить роль.

Листинг 1: Actor

//Принять или отклонить роль
function TActor.CanAcceptRole(ARoleClass: TRoleClass): Boolean;
begin
if not ARoleClass.AllowDuplicates and HasRole(ARoleClass, nil) then
Result := False
else
if not ARoleClass.AllowActiveDuplicates and
HasActiveRole(ARoleClass, nil) then
Result := False
else
Result := ARoleClass.CanApplyTo(Self);
end;



//Разрешить или запретить удаление роли
function TActor.CanRemoveRole(ARole: TRole): Boolean;
begin
Result := not ARole.IsRequired;
end;



//Возвращает роль, только если она активна
function TActor.FindActiveRole(AClass: TClass; ExcludeInstance: TRole): TRole;
var
I: Integer;
begin
Result := nil;
for I := 0 to Roles.Count - 1 do
if Roles[I].Active and (Roles[I].ClassType = AClass) and
(Roles[I] <> ExcludeInstance) then
begin
Result := Roles[I];
Break;
end;
end;



//Возвращает роль вне зависимости от её активности
function TActor.FindRole(AClass: TClass; ExcludeInstance: TRole): TRole;
var
I: Integer;
begin
Result := nil;
for I := 0 to Roles.Count - 1 do
if (Roles[I].ClassType = AClass) and
(Roles[I] <> ExcludeInstance) then
begin
Result := Roles[I];
Break;
end;
end;



//Возвращает True, если Актор владеет указанной ролью и она активна
function TActor.HasActiveRole(AClass: TClass; ExcludeInstance: TRole): Boolean;
begin
Result := Assigned(FindActiveRole(AClass, ExcludeInstance));
end;



//Возвращает True, если Актор владеет указанной ролью (активной или неактивной)
function TActor.HasRole(AClass: TClass; ExcludeInstance: TRole): Boolean;
begin
Result := Assigned(FindRole(AClass, ExcludeInstance));
end;



function TActor.ReceiveQueryFromOwned(Originator: TObject; OriginalEvent: TBoldEvent;
const Args: array of const; Subscriber: TBoldSubscriber): Boolean;
var
ObjectLocator: TBoldObjectLocator;
Role: TRole;
begin
Result := inherited ReceiveQueryFromOwned(Originator, OriginalEvent, Args, Subscriber);
if not Result or BoldObjectIsDeleted then Exit; //Проверка добавления ролей
if (Originator = M_Roles) then
begin
if OriginalEvent = bqMayInsert then
begin
//Получить добавляемую роль
Assert(Args[1].VType = vtObject);
ObjectLocator := (Args[1].VObject as TBoldObjectLocator);
Role := (ObjectLocator.BoldObject as TRole); //Проверка дублирующихся ролей, которые не разрешены
if (not Role.AllowDuplicates) and
(HasRole(Role.ClassType, nil)) then
begin
Result := False;
SetBoldLastFailureReason(
TBoldFailureReason.Create('Эта роль может быть применена только один раз', Self)
);
end else
//Проверка дублирующихся активных ролей, которые не разрешены
if (not Role.AllowActiveDuplicates) and
(HasActiveRole(Role.ClassType, nil)) then
begin
Result := False;
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно применить эту роль, так как ' +
'уже существует активная роль такого типа', Self)
);
end else
Result := CanAcceptRole(TRoleClass(Role.ClassType));
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Роль не может быть применена к этому объекту', Self)
);
end else //bqMayInsert
//Проверка удаления ролей
if OriginalEvent = bqMayRemove then
begin
//Получить удаляемый объект роли
Assert(Args[0].VType = vtInteger);
Role := Roles[Args[0].VInteger];
Result := (not Role.Active) or (not Role.IsRequired);
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Роль не может быть удалена, ' +
'она требуется другой активной ролью', Self)
);
end; //bqMayRemove
end;
end;

Листинг 2: Role

//Разрешить или запретить применение к конкретному Актору
class function TRole.CanApplyTo(AObject: TActor): Boolean;
begin
Result := False;
end;



//Виртуальный метод для переопределения в потомках, описывающий роль
class function TRole.GetRoleName: string;
begin
Result := '';
end;



//Опционально, указывает, разрешены ли активные дубликаты
class function TRole.AllowActiveDuplicates: Boolean;
begin
Result := False;
end;



//Опционально, указывает, разрешены ли дубликаты (активные или неактивные)
class function TRole.AllowDuplicates: Boolean;
begin
Result := False;
end;



//Возвращает True, если какая-либо роль зависит от наличия этой роли
function TRole.IsRequired: Boolean;
var
I: Integer;
begin
if Actor <> nil then
begin
Result := True;
for I := 0 to Actor.Roles.Count - 1 do
if Actor.Roles[I] <> self then
if Actor.Roles[I].RequiresRole(self) then
Exit;
end;
Result := False;
end;



//Переопределите этот метод, чтобы указать зависимость от другой роли
function TRole.RequiresRole(ARole: TRole): Boolean;
begin
Result := False;
end;



//Заполняет производный атрибут RoleName из метода класса
procedure TRole._RoleName_DeriveAndSubscribe(DerivedObject: TObject; Subscriber: TBoldSubscriber);
begin
inherited;
M_RoleName.AsString := GetRoleName;
end;



//Предотвращает удаление обязательной роли
function TRole.MayDelete: Boolean;
begin
Result := not IsRequired;
end;



function TRole.ReceiveQueryFromOwned(Originator: TObject; OriginalEvent: TBoldEvent;
const Args: array of const; Subscriber: TBoldSubscriber): Boolean;
begin
Result := inherited ReceiveQueryFromOwned(Originator,
OriginalEvent, Args, Subscriber);
if not Result then Exit;
if (Originator = M_Active) then //Атрибут Active
begin
if OriginalEvent = bqMayModify then
begin
if Actor = nil then
Result := True
else
if Active then
begin
//Запретить деактивацию, если другая роль требует,
//чтобы эта роль была активна
Result := not IsRequired;
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно деактивировать эту роль, ' +
'другие роли зависят от неё', Self)
);
end else
begin
//Запретить повторную активацию, если уже существует активная роль
//и дубликаты не разрешены
Result := AllowActiveDuplicates or (not Actor.HasActiveRole(Self.ClassType, Self));
if not Result then
SetBoldLastFailureReason(
TBoldFailureReason.Create('Невозможно активировать эту роль, ' +
'так как уже существует похожая активная роль', Self)
);
end;
end; //bqMayModify
end; //Атрибут Active
end;

Весь приведённый выше код является абстрактным. Остаётся лишь создать конкретные классы, унаследованные от Actor и Role.

UMLRoles.jpg

Заключение

Вместо того чтобы иметь отдельные классы Employee и Customer, мы теперь можем легко назначить EmployeeRole или CustomerRole любому объекту типа Person (который является Актором).

Кроме того, роли можно комбинировать: пилот может выполнять административную работу, а клиентом может быть кто угодно — человек, отдел, компания или даже страна.

Надеюсь, эта статья оказалась полезной.

Ролевое программирование в Bold

Пример реализации паттерна Актор/Роль в Bold.
рекомендовать друзьям
  • gplus
  • pinterest

Комментарий

Оставить комментарий

Оценивать